拡張子無しのファイル名を取得する方法

Option Explicit
 
Dim objFileSys
 
'ファイルシステムを扱うオブジェクトを作成
Set objFileSys = CreateObject("Scripting.FileSystemObject")
 
'拡張子無しのファイル名を取得（絶対パス指定の場合）
'「顧客リスト」と表示される。
WScript.Echo objFileSys.getBaseName("c:\temp\顧客リスト.xlsx")
 
'拡張子無しのファイル名を取得（相対パス指定の場合）
'「summer」と表示される。
WScript.Echo objFileSys.getBaseName("summer.jpg") 

Option Explicit
 
Dim objFileSys
Dim objWriteStream
Dim objFolder
Dim objFile
Dim strPathTargetDir
Dim strPathOutputText
 
'対象のフォルダを指定。このフォルダ内にあるファイルの一覧を作成する。
strPathTargetDir = "c:\temp"
 
'出力先のファイルのパスを指定。ここにファイルの一覧を書き出す。
strPathOutputText = ".\output.txt"
 
'ファイルシステムを扱うオブジェクトを作成
Set objFileSys = CreateObject("Scripting.FileSystemObject")
 
'出力先のファイルを開く（上書きモード）
Set objWriteStream = objFileSys.OpenTextFile(strPathOutputText, 2, True)
 
'対象のフォルダのオブジェクトを取得
Set objFolder = objFileSys.GetFolder(strPathTargetDir)
 
'FolderオブジェクトのFilesプロパティからFileオブジェクトを取得
For Each objFile In objFolder.Files
  '取得したファイルの拡張子無しファイル名を取得し、ファイルに出力
  objWriteStream.WriteLine objFileSys.getBaseName(objFile.Name)
Next
 
'出力先のファイルを閉じる
objWriteStream.Close
 
Set objWriteStream = Nothing
Set objFileSys = Nothing