ストアドプロシージャを実行して戻り値を受け取る方法

Option Explicit
 
Sub test()
    '■接続先情報を設定
    'この例では、ローカルのインスタンス「SQLEXPRESS」にWindows認証で接続する。
    Dim connectionString As String
    
    Dim dataSourceName As String
    Dim databaseName As String
    
    '「.」はローカルを表す。他のサーバに接続する場合はホスト名を指定。
    dataSourceName = ".\SQLEXPRESS" '
    
     'TESTデータベースに接続する。
    databaseName = "TEST"
    
    'ODBC接続の接続文字列を作成する。
    connectionString = ""
    connectionString = connectionString & "PROVIDER=MSDASQL;"
    connectionString = connectionString & "DRIVER={SQL Server};"
    connectionString = connectionString & "SERVER=" & dataSourceName & ";"
    connectionString = connectionString & "INITIAL CATALOG=" & databaseName & ";"
    connectionString = connectionString & "Trusted_connection=yes; "
    
    '■接続
    Dim objConnection As ADODB.Connection
    
    Set objConnection = New ADODB.Connection
    
    objConnection.CursorLocation = adUseClient
    objConnection.Open connectionString
    
    '■実行するストアドプロシージャを設定
    Dim objCommand As ADODB.Command
    
    Set objCommand = New ADODB.Command
    Set objCommand.ActiveConnection = objConnection
    
    objCommand.CommandType = adCmdStoredProc
    objCommand.CommandText = "TEST_PROC"
    
    '■戻り値を受け取るパラメータを設定
    Dim objParameter As ADODB.Parameter
    
    Set objParameter = objCommand.CreateParameter()
    objParameter.Name = "ReturnValue" '引数の名前（任意の名前）
    objParameter.Type = adInteger '数値
    objParameter.Direction = adParamReturnValue '戻り値
    objParameter.Value = Null
    
    objCommand.Parameters.Append objParameter
    
    '■ストアドを実行
    objCommand.Execute
        
    '■ストアドの戻り値を取得
    Dim returnValue As Integer
    returnValue = objCommand.Parameters("ReturnValue").Value
    
    Debug.Print "受け取った戻り値→" & returnValue
    
    '■終了処理
    Set objParameter = Nothing
    Set objCommand = Nothing
    Set objConnection = Nothing
End Sub