UPDATE文を実行して更新件数を取得する方法

Option Explicit
 
Sub test()
    '■接続先情報を設定
    'この例では、ローカルのインスタンス「SQLEXPRESS」にWindows認証で接続する。
    Dim connectionString As String
    
    Dim dataSourceName As String
    Dim databaseName As String
    
    '「.」はローカルを表す。他のサーバに接続する場合はホスト名を指定。
    dataSourceName = ".\SQLEXPRESS" '
    
     'TESTデータベースに接続する。
    databaseName = "TEST"
    
    'ODBC接続の接続文字列を作成する。
    connectionString = ""
    connectionString = connectionString & "PROVIDER=MSDASQL;"
    connectionString = connectionString & "DRIVER={SQL Server};"
    connectionString = connectionString & "SERVER=" & dataSourceName & ";"
    connectionString = connectionString & "INITIAL CATALOG=" & databaseName & ";"
    connectionString = connectionString & "Trusted_connection=yes; "
    
    '■接続
    Dim objConnection As ADODB.Connection
    
    Set objConnection = New ADODB.Connection
    
    objConnection.CursorLocation = adUseClient
    objConnection.Open connectionString
    
    '■実行するSQLを設定
    Dim objCommand As ADODB.Command
    Set objCommand = New ADODB.Command
    
    Dim sql As String
    
    sql = ""
    sql = sql & " UPDATE"
    sql = sql & "     TEST.dbo.TEST_TABLE"
    sql = sql & " SET"
    sql = sql & "     MEMO = 'さん以下'"
    sql = sql & " WHERE"
    sql = sql & "     ID <= 3;"
    
    Set objCommand.ActiveConnection = objConnection
    
    objCommand.CommandType = adCmdText
    objCommand.CommandText = sql
    
    '■更新件数を受け取る変数を準備
    Dim affectedRowNum As Long
    
    '■SQLを実行
    objCommand.Execute affectedRowNum
    
    '■更新件数を表示
    Debug.Print "更新された件数→" & affectedRowNum
    
    '■終了処理
    Set objCommand = Nothing
    Set objConnection = Nothing
End Sub